5 PRINT"[147]":POKE53281,6:POKE53280,14:POKE646,14
10 DIM S(20),L(12):CR=68:PRINT"[147]GOLF HANDICAP CALCULATOR"
20 INPUT"ENTER PLAYER'S NAME";PN$:IF PN$="" THEN PRINT"[145][145]";:GOTO20
30 F$=LEFT$(PN$,12)+".DAT"
40 OPEN 2,8,2,F$:OPEN15,8,15:INPUT#15,A$,B$:CLOSE15
50 IF A$="62" THEN CLOSE2:GOSUB340:GOTO100
60 CLOSE2:OPEN 2,8,2,F$:VM=20.1
70 FOR I=1 TO 20:INPUT#2,S(I):IF S(I)<0 THEN VM=I:I=20
80 NEXT I:CLOSE2:IF VM=20.1 THEN VM=20:FOR I=0 TO 19:S(I)=S(I+1):NEXT
90 INPUT"ENTER NEW SCORE";S(VM):IF VM<20 THEN S(VM+1)=-1
100 Q=1:L(1)=S(1):QM=11:IF VM<QM THEN QM=VM
110 FOR I=2 TO VM
120 FOR J=1 TO Q
130 IF S(I)<L(J) THEN FOR K=Q TO J STEP-1:L(K+1)=L(K):NEXT:L(J)=S(I):J=Q+10
140 NEXT J:Q=Q+1:IF Q>QM THEN Q=QM
150 IF J<=Q THEN L(Q)=S(I)
160 NEXT I
170 IF VM=20 THEN PRINT"THE LAST TWENTY SCORES:":GOTO190
180 PRINT""VM"SCORES:"
190 FORI=1 TO VM:PRINTS(I);"[157]";:IF I=10 THEN PRINT
200 NEXT:PRINT
210 T=0:PRINT"LOW SCORES USED IN COMPUTATION:"
220 IF VM<5 THEN PRINT"5 OR MORE SCORES NEEDED FOR HANDICAP.":GOTO280
230 IF VM<17 THEN M%=1+(VM-5)/2
240 IF VM>16 THEN M%=VM-10
250 FOR I=1 TO M%:PRINT L(I)"[157]";:T=T+L(I)-CR:NEXT:T=T/M%*10:H=INT(T*.096+.5)
260 PRINT:PRINT"HANDICAP:";:IFH<0THENPRINT" +";
270 PRINTABS(H)
280 PRINT"SAVE TO DISK (Y/N)?":GOSUB460
290 IF R=0 THEN330
300 OPEN 15,8,15:PRINT#15,"S0:";F$:CLOSE15
310 OPEN 2,8,1,F$
320 FOR I=1 TO VM:PRINT#2,S(I):NEXT:PRINT#2,-1:CLOSE2
330 END
340 PRINT"A NEW PLAYER"
350 PRINT"ENTER "PN$"'S LAST TWENTY SCORES"
360 PRINT"IF YOU DON'T HAVE 20, ENTER -1 AFTER    LAST SCORE"
370 FOR V=1 TO 20:INPUT S(V)
380 VM=V:IF S(V)=-1 THEN VM=V-1:V=20
390 NEXT
400 PRINT"[147]"PN$"'S LAST"VM"SCORES:"
410 FOR I=1 TO VM:PRINT "#"I"  SCORE"S(I):NEXT
420 PRINT"ARE THESE SCORES OKAY (Y/N)?":GOSUB460
430 IF R THEN RETURN
440 INPUT"ENTER # OF BAD SCORE";N:IF N<1 OR N>VM THEN PRINT"[145]";:GOTO440
450 PRINT"CORRECT #";N;:INPUT S(N):GOTO400
460 GETA$:IF A$="Y" THEN R=1:RETURN
470 IF A$="N" THEN R=0:RETURN
480 GOTO460